Microsoft Access 掲示板

慧眼のhatenaさんが仰せのように、もし 連続した複数文字列を対象 とするのでしたら
「連続」の定義、つまり最小で何文字連続している必要があるのか
を明確にする必要があるでしょう

テキストボックスA ＝ "あいうえおかきく"
テキストボックスB ＝ "[@あいうえお@おかき@きくうえお@いうえおかういあいうえおかきおかく]"

Bの文字列で「 連続３文字以上で構成された語句でAに対する最長マッチ 」を繰り返す
と定義した場合、

[@あいうえお@おかき@きくうえお@いうえおかういあいうえおかきおかく]

Bからは、背景色を付与した５箇所の語句を検知( グレーアウト部分は長さが不足 )し、
最終的に

テキストボックスB ＝ "[@@@きく@ういおかく]"

をご希望の結果とするサンプルも載せておきます
　

Function OnesideUniqueX(ByVal argA As Variant _
                      , ByVal argB As Variant _
                      , Optional ByVal argMinimum As Long = 3 _
                      , Optional ByVal argPos As Long = 1) As Variant
    OnesideUniqueX = argB
    Dim i    As Long
    Dim j    As Long
    Dim buff As String

    If (LenB(Nz(argA)) = 0 Or LenB(Nz(argB)) = 0) Then Exit Function
    If (argMinimum < 1 Or argPos < 1) Then Exit Function

    For i = argPos To Len(argB) - argMinimum + 1
        If (InStr(1, argA, Mid$(argB, i, argMinimum), vbBinaryCompare) > 0) Then
            buff = Mid$(argB, i, argMinimum)

            For j = i + argMinimum To Len(argB)
                buff = buff & Mid$(argB, j, 1)
                If (InStr(1, argA, buff, vbBinaryCompare) = 0) Then
                    OnesideUniqueX = _
                        OnesideUniqueX(argA, Left$(argB, i - 1) & Mid$(argB, j), argMinimum, i)
                    Exit Function
                End If
            Next j
            OnesideUniqueX = Left$(argB, Len(argB) - Len(buff))
            Exit Function
        End If
    Next i
End Function

Private Sub コマンドボタン名_Click()
    '// 重複と見なす文字列の最小連続長は関数の第三引数で指定します
    Me.テキストボックスB.Value = _
        OnesideUniqueX(Me.テキストボックスA.Value, Me.テキストボックスB.Value, 3)
End Sub

Bの文字列で「 連続３文字以上で構成された語句でAに対する最長マッチ 」を繰り返す
と定義した場合、

mayuさんの上記の定義を仕様とする場合は下記のコードでもよさそう。

Function RemoveDuplicatesX(ByVal argA As Variant _
                      , ByVal argB As Variant _
                      , Optional ByVal argMinimum As Long = 3) As Variant
    RemoveDuplicatesX = argB
    Dim lA As Long, lB As Long, l As Long
    lA = Len(Nz(argA))
    lB = Len(Nz(argB))
    If lA < argMinimum Or lB < argMinimum Then Exit Function
    If lB < lA Then l = lB Else l = lA
    
    Dim i As Long, j As Long
    For i = l To argMinimum Step -1
        For j = 1 To lA - i
            RemoveDuplicatesX = Replace(RemoveDuplicatesX, Mid(argA, j, i), "")
        Next
    Next
End Function

Private Sub コマンドボタン名_Click()
    '// 重複と見なす文字列の最小連続長は関数の第三引数で指定します(省略時は3)
    Me.テキストボックスB.Value = _
        RemoveDuplicatesX(Me.テキストボックスA.Value, Me.テキストボックスB.Value)
End Sub