Microsoft Access 掲示板

DoCmdは「ACCESS」の機能を呼び出します
「ACCESS」は、自身がどんなフォームがあるだとか、そこにどんなコントロールがあるだとか認識できます。なので、クエリ実行時（DoCmd.RunSQL）にForms![F_改修履歴に追加設定]![tx受付日付代入用]が何者か判断できます

CurrentDb.Executeは「DAO」の機能を呼び出します
「DAO」はACCESSの構文を解釈する機能はないので、Forms![F_改修履歴に追加設定]![tx受付日付代入用]を一つの、そのような名称のパラメータ（変数）として解釈しようとします。結果、そのようなパラメータを用意していないDAOを実行しようとして、パラメータが少なすぎますとエラーを返してきています

CurrentDb.Executeを使うのであれば、DAOで実行する前に、VBAで値の変換を済ませておく（strSQLの中にフィールド指定の構文を入れない）必要があります

strSQL = _
    " INSERT INTO T_登録中継用_改修履歴" & _
          " (製造履歴ID, 受付日付, 改修内容, 完了日付, MEMO)" & _
    " SELECT" & _
          " 製造履歴ID" & _
          ", #" & Forms![F_改修履歴に追加設定]![tx受付日付代入用] & "#" & _
          ", '" & Forms![F_改修履歴に追加設定]![tx改修内容代入用] & "'" & _
          ", #" & Forms![F_改修履歴に追加設定]![tx完了日付代入用] & "#" & _
          ", '" & Forms![F_改修履歴に追加設定]![tx_memo代入用] & "'" & _
    " FROM T_製造履歴" & _
    " WHERE check=True;"

参考
パラメータクエリを含むSQLをVBAから実行する（hatena chipsさん）

英語でのエラーだと、たとえば

"Run-time error '3061'. Too few parameters. Expected 1."

のようになるようです。ネイティブならすんなり意味が分かるんでしょうか。日本語にするなら

”実行時ｴﾗｰ'3061'
パラメータが少なすぎます。パラメータが1つ必要です。”

隠れた文字が表現されているといいと思いますし、意訳して「パラメータが1つ不足しています」とかなるとわかりやすいんじゃないかと

実行時ｴﾗｰ'3061'
パラメータが少なすぎます。4を指定して下さい。

変数 strSQL に格納されている SQL がパラメータクエリになっているからです。

Forms![F_改修履歴に追加設定]![tx受付日付代入用]

Forms![F_改修履歴に追加設定]![tx改修内容代入用]

Forms![F_改修履歴に追加設定]![tx完了日付代入用]

Forms![F_改修履歴に追加設定]![tx_memo代入用]

以上の 4 箇所がそれぞれ暗黙的なパラメータとして認識されています。

そして DAO.Database オブジェクトの Execute メソッドでは、
パラメータへの値渡しを行うことが出来ません。

この場合は、次のいずれかの方法を用いるのが妥当です。

• フォーム[F_改修履歴に追加設定]がフォームビューで開かれている状態で、DoCmd オブジェクトの RunSQL メソッドを呼び出す（ QBF 技法）。

'Access のシステムメッセージの表示を無効にする
DoCmd.SetWarnings False
'Access の[SQL の実行]アクションを呼び出す
DoCmd.RunSQL strSQL
'Access のシステムメッセージの表示を有効にする
DoCmd.SetWarnings True

• DAO.Database オブジェクトの CreateQueryDef メソッドにより一時的な QueryDef オブジェクトを作成し、Parameters プロパティ（コレクション）を介して値渡しを行った上、その QueryDef オブジェクトの Execute メソッドを呼び出す。

'フォーム[F_改修履歴に追加設定]のフォームモジュールから実行する場合

Dim dbTarget As DAO.Database
Dim qdfTemp As DAO.QueryDef
Dim lngInsertedCount As Long

'カレントデータベースの参照
Set dbTarget = CurrentDb
'一時的なクエリを作成する
Set qdfTemp = dbTarget.CreateQueryDef("", strSQL)

With qdfTemp
    '各パラメータに値を渡す
    .Parameters("Forms![F_改修履歴に追加設定]![tx受付日付代入用]").Value = Me![tx受付日付代入用].Value
    .Parameters("Forms![F_改修履歴に追加設定]![tx改修内容代入用]").Value = Me![tx改修内容代入用].Value
    .Parameters("Forms![F_改修履歴に追加設定]![tx完了日付代入用]").Value = Me![tx完了日付代入用].Value
    .Parameters("Forms![F_改修履歴に追加設定]![tx_memo代入用]").Value = Me![tx_memo代入用].Value
    'クエリを実行する
    .Execute dbFailOnError
    'クエリによって影響を受けたレコードの件数を取得する
    lngInsertedCount = qdfTemp.RecordsAffected
End With

Set qdfTemp = Nothing
Set dbTarget = Nothing

If lngInsertedCount > 0 Then
    MsgBox "[T_登録中継用_改修履歴]に " & lngInsertedCount & " 件のレコードが追加されました。", _
           vbInformation, _
           "実行完了"
Else
    MsgBox "追加対象となるレコードがありません。", _
           vbInformation, _
           "対象レコードなし"
End If

後者の方法は、主に以下のようなケースにおいて用いるのが適しています。

• 特定のインターフェース（この場合はフォーム）に依存せず、パラメータに任意の値を直接渡したい場合

• 実行されたクエリ/SQLによって影響を受けたレコードの件数を取得したい場合

• DAO.Workspace オブジェクトと連携してトランザクション処理を行いたい場合

hirotonさん　skさん　詳細な回答ありがとうございました。なりほどそういう事だったのですね。
因みに前回質問分でhirotonさんとhatenaさんから回答頂いた下記はCurrentDb.Execute strSQLでいけたのですが、これは何故でしょうか？　更新と追加の違いはありますが（完全に理解出来てなくすみません）

Dim strSQL As String
If Not IsNull(Me!change_Date) Then strSQL = ", [完成日付]=" &  Format(Me!change_Date, "#yyyy/mm/dd#")
If IsDate(Me!change_Kokyaku) Then strSQL = strSQL & ", [顧客ID]=" & Me!change_Kokyaku
If Not IsNull(Me!change_Firm) Then strSQL = strSQL & ", [firmID]=" & Me!change_Firm
If Not IsNull(Me!change_Tanto) Then strSQL = strSQL & ", [製造担当者ID]=" & Me!change_Tanto
If Not IsNull(Me!change_Biko) Then strSQL = strSQL & ", [備考]='" & Me!change_Biko & "'"

If strSQL = "" Then Exit Sub

strSQL = "UPDATE [T_製造履歴] SET " & Mid(strSQL, 3) & " WHERE [check]=True;"

skさん　ありがとうございます。フィールドの名前とも一致しない識別子の事も大変重要ですね。今まで認識してなかったので勉強になりました。ACCESSは名前で判断されるので注意が必要ですね。
確かに「I'm sorry.」ではエラー出ましたのでReplace･･･にしたらＯＫでした。
細かい設定をしないと、どこでエラーになるか分かりませんね、いい経験となりました。ACCESSは奥が深く大変ですが、コツコツするしかありません。色々な事を教えて頂けて大変有り難いです。
本当に感謝です。